@echo off
rem ------------------------------------------------------------------------
rem Thunderbird を終了させてからｄポイントのメールを修正したフォルダーを作成
rem その後Thunderbirdを起動し直す
rem ------------------------------------------------------------------------

rem ■環境変数定義（"="の前後に空白入れない）
rem -- 固定 --
set SEDCMD="s/multipart\/mixed;/multipart\/related;/"
set SED="C:\Program Files (x86)\GnuWin32\bin\sed.exe"
set WSL=C:\Windows\System32\wsl.exe
set APP_NAME=thunderbird.exe
rem -- 以下を環境に合わせて変更 --
rem   Thunderbird の起動に使っているショートカットのリンク先の内容そのままを設定
set APP_CMD="C:\Program Files\Mozilla Thunderbird\thunderbird.exe"
rem   置換元のフォルダーファイルのフルパス（ダブルクォーテーションで囲わない）
set INPUT_MBOX=C:\Users\□□\AppData\Roaming\Thunderbird\Profiles\xxxxxxxx.△△\Mail\Local Folders\d-point.sbd\d-point(pre-fix)
rem   置換先のフォルダーファイルのフルパス（ダブルクォーテーションで囲わない）
set OUTPUT_MBOX=C:\Users\□□\AppData\Roaming\Thunderbird\Profiles\xxxxxxxx.△△\Mail\Local Folders\d-point

rem ■GnuWin32のsedコマンドを使っているので存在しているか調べる
if not exist %SED% (
  echo ===================================================
  echo %SED% がありません
  echo GnuWin32 の sedコマンド をインストールしてください
  echo ===================================================
  pause
  echo " "
  exit /b 0
)

rem ■Thunderbird が起動しているか調べる
tasklist /nh | find "%APP_NAME%" > nul
if errorlevel 1 (
  set IS_RUN=0
  goto END_KILLCHK
) else (
  set IS_RUN=1
)

rem ■Thunderbird 終了
echo -----------------------------------------------------------------------
echo ｄポイントからのメールを修正するために Thunderbird をいったん終了します
echo -----------------------------------------------------------------------
rem 任意のキー入力を待つ
pause

rem thunderbird.exe を終了させる（複数の thunderbird.exe が起動していた場合はそのすべてが対象）
taskkill /IM %APP_NAME%

rem 終了を待つ
:LOOP_KILLCHK
  tasklist /nh | find "%APP_NAME%" > nul
  tasklist /nh /fi "imagename eq %APP_NAME%" | find ":" > nul
  if errorlevel 1 goto END_KILLCHK
  timeout /t 1
  goto LOOP_KILLCHK
:END_KILLCHK

rem ■sedでメールフォルダーを置換して書きだす
if exist "%OUTPUT_MBOX%" (
  del /f "%OUTPUT_MBOX%"
)
if exist "%OUTPUT_MBOX%.msf" (
  del /f "%OUTPUT_MBOX%.msf"
)
echo "%INPUT_MBOX% => %OUTPUT_MBOX%"
%SED% -e %SEDCMD% < "%INPUT_MBOX%" > "%OUTPUT_MBOX%"

rem ■Thunderbird を起動
if %IS_RUN% equ 1 (
  echo Thunderbird を起動します
  start " " %APP_CMD%
)

set SED="C:\Program Files (x86)\GnuWin32\bin\sed.exe"